COMMENT ⊗   VALID 00006 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002	delimiters ()
C00005 00003	"straight V"
C00006 00004	"changed to leave a notch"
C00007 00005	"same, with the bottom filled in"
C00008 00006	end
C00009 ENDMK
C⊗;
delimiters ();
def tracingall=tracingcommands:=3;
 tracingedges:=1; tracingtitles:=1; tracingequations:=1; tracingspecs:=2;
	tracingpens:=1; tracingchoices:=1; tracingstats:=2;
 tracingonline:=1;tracingoutput:=1;tracingmacros:=3 enddef;
%tracingall;

def down=(0,-1) enddef;
def up=(0,1) enddef;
def right=(1,0) enddef;
def left=(-1,0) enddef;

vardef z@#=(x@#,y@#) enddef;

edges e;
e=nulledges;

def draw expr x = addto e contour x withweight 1 enddef;
def erase expr x = addto e contour x withweight -1 enddef;

openwindow 1 from (0,0) to (400,450) at (-100,300);

smoothing:=1; autorounding:=3;

hppp:=240/72.27;
vppp:=hppp;
charcode:=97;

def next=
	display e on 1;
	shipout e;
	e:=nulledges; numeric x[],y[],x[]l,x[]r,y[]l,y[]r;
	charcode:=charcode+1
enddef;

def toplabel = makelabel(" 1") enddef;
def leftlabel = makelabel(" 2") enddef;
def rightlabel = makelabel(" 3") enddef;
def botlabel = makelabel(" 4") enddef;
def autolabel = makelabel(" 5") enddef;
def makelabel(expr s)(text t) =
	forsuffixes $:=t:
	special s&str$; numspecial x$; numspecial y$; endfor enddef;
def proofrule(expr a,b) =
	special "rule"; numspecial xpart a; numspecial ypart a;
	numspecial xpart b; numspecial ypart b enddef;
def proofoffset primary x =
	special "offset"; numspecial xpart x; numspecial ypart x enddef;

proofing:=1;
"straight V";

capheight=150;
thickwidth=50; thinwidth=40;
rightedge=125;

x1l=0; x1r=x1l+thickwidth;
x2l=x2r-thinwidth; x2r=rightedge;
y1l=y1r=y2l=y2r=capheight;
y3l=y3r=y4l=y4r=0;
x3l-x1l=x2r-x4r;
x4r-x3l=1.1thickwidth;
x3r-x3l=thickwidth; x4r-x4l=thinwidth;

draw z3l..z1l&z1l..z1r&z1r..z3r&z3r..z3l&cycle;
draw z4r..z2r&z2r..z2l&z2l..z4l&z4l..z4r&cycle;

autolabel(1l,1r,2l,2r,3l,3r,4l,4r);
next;
"changed to leave a notch";

notchheight=(thickwidth+thinwidth)/2;

x1l=0; x1r=x1l+thickwidth;
x2l=x2r-thinwidth; x2r=rightedge;
y1l=y1r=y2l=y2r=capheight;
y3l=y3r=0;
x3l-x1l=x2r-x3r;
x3r-x3l=1.1thickwidth;
y4=notchheight;
(x4-x3l)/(x3r-x3l) = thickwidth/(thickwidth+thinwidth);

draw z3l..z1l&z1l..z1r&z1r{z3l-z1l}..z4-(.5,0){down}..z3l{left}&cycle;
draw z3r..z2r&z2r..z2l&z2l{z3r-z2r}..z4+(.5,0){down}..z3r{right}&cycle;

autolabel(1l,1r,2l,2r,3l,3r,4);
next;
"same, with the bottom filled in";

x1l=0; x1r=x1l+thickwidth;
x2l=x2r-thinwidth; x2r=rightedge;
y1l=y1r=y2l=y2r=capheight;
y3l=y3r=0;
x3l-x1l=x2r-x3r;
x3r-x3l=1.1thickwidth;
y4=notchheight;
(x4-x3l)/(x3r-x3l) = thickwidth/(thickwidth+thinwidth);

draw z3l..z1l&z1l..z1r&z1r{z3l-z1l}..z4-(.5,0){down}..z3l{left}&cycle;
draw z3r..z2r&z2r..z2l&z2l{z3r-z2r}..z4+(.5,0){down}..z3r{right}&cycle;
draw z4{right}..z3r{down}&z3r..z3l&z3l{up}..cycle;

autolabel(1l,1r,2l,2r,3l,3r,4);
next;
end